毒っぽい表現をシェーダーでやってみる

Shader "Unlit/S_FlowGradient"
{
    Properties
    {
        _MainTex ("Main Texture", 2D) = "white" {}
        _Gradient ("Gradient", 2D) = "white" {}
        _Size ("Size", Vector) = (512, 512, 0, 0)
        _TimeSpeed ("Time Speed", Float) = 0.025
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" "Queue"="Transparent" }
        Blend SrcAlpha OneMinusSrcAlpha
        Cull Off ZWrite Off ZTest Always

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            sampler2D _MainTex;
            sampler2D _Gradient;
            float4 _MainTex_ST;
            float4 _Size;
            float _TimeSpeed;

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
            };

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                // UV調整
                float2 uv = i.uv * (_Size.xy / float2(512.0, 512.0));

                float timeOffset = _Time.y * _TimeSpeed;

                float t0 = tex2D(_MainTex, uv).r;
                float t1 = tex2D(_MainTex, uv - float2(timeOffset, timeOffset)).r;
                float t2 = tex2D(_MainTex, uv + float2(timeOffset, timeOffset)).r;

                float t12 = (t1 + t2);
                float offset = (t0 + t12) * 0.5;

                // offsetをUVにする
                float t3 = tex2D(_MainTex, float2(offset, offset)).r;
                float contrast = t3 * t12;

                float2 gradUV = float2(contrast, 0.0);
                float3 color = tex2D(_Gradient, gradUV).rgb;

                return float4(color, 1.0);
            }
            ENDCG
        }
    }
}